module lang::cobol85::\syntax::InputOutputSection
rascal-0.43.3
org.rascalmpl.cobol-air-0.1.2
The INPUT-OUTPUT SECTION: FILE-CONTROL entries and I-O-CONTROL entries.
Usage
import lang::cobol85::\syntax::InputOutputSection;
Dependencies
extend lang::cobol85::\syntax::FileDescriptionEntry;
extend lang::cobol85::\syntax::Expression;
Description
This module defines the SELECT entries of the FILE-CONTROL paragraph, which connect a file name to external storage with ASSIGN and describe it with clauses for organization (sequential, relative, indexed), access mode, record and alternate record keys, relative key, file status, reserved areas, padding character, record delimiter and password. The clauses may come in any order, also before ASSIGN, as some programs write them. The module also defines the entries of the I-O-CONTROL paragraph: RERUN, SAME AREA (also SAME RECORD and SAME SORT AREA), MULTIPLE FILE TAPE and APPLY. Orders and combinations that COBOL does not allow are left to a checker.
syntax FileControlClause
syntax FileControlClause
= record: 'RECORD' 'KEY'? 'IS'? QualifiedDataName
| access: 'ACCESS' 'MODE'? 'IS'? AltSequentialRandomDynamic
| relativeKey: 'RELATIVE' 'KEY'? 'IS'? QualifiedDataName
| recordDelimiter: 'RECORD' 'DELIMITER' 'IS'? RecordDelimiterName
| status: 'FILE'? 'STATUS' 'IS'? QualifiedDataName QualifiedDataName?
| padding: 'PADDING' 'CHARACTER'? 'IS'? AltQualifiedDataNameLiteral
| organization: 'ORGANIZATION'? 'IS'? AltIndexedRelativeSequential
| passwordClause: PasswordClause
| alternate: 'ALTERNATE' 'RECORD'? 'KEY'? 'IS'? QualifiedDataName PasswordClause?
| duplicates: 'WITH'? 'DUPLICATES'
| reserve: 'RESERVE' Integer Areas?
;
syntax AltSequentialRandomDynamic
syntax AltSequentialRandomDynamic
= random: 'RANDOM'
| \dynamic: 'DYNAMIC'
| sequential: 'SEQUENTIAL'
;
syntax RecordDelimiterName
syntax RecordDelimiterName
= assignmentName: Id
| standard1: 'STANDARD-1'
;
syntax AltIndexedRelativeSequential
syntax AltIndexedRelativeSequential
= relative: 'RELATIVE'
| indexed: 'INDEXED'
| sequential: 'SEQUENTIAL'
;
syntax PasswordClause
syntax PasswordClause = password: 'PASSWORD' 'IS'? Id;
syntax Areas
syntax Areas
= areas: 'AREAS'
| area: 'AREA'
;
syntax IoControlEntry
syntax IoControlEntry
= rerun: 'RERUN' 'ON' Id ('EVERY'? EveryPhrase 'OF'? Id)?
// SAME SORT AREA FOR SQ-FS1 ST-FS1,
| same: 'SAME' RecordSort? 'AREA'? 'FOR'? Id Id+
| apply: 'APPLY' 'WRITE-ONLY' 'ON'? Id+
| multiple: 'MULTIPLE' 'FILE' 'TAPE'? 'CONTAINS'? FileNamePosition+
;
syntax EveryPhrase
syntax EveryPhrase
= end: 'END' 'OF'? AltReelUnit
| records: Integer 'RECORDS'
;
syntax RecordSort
syntax RecordSort
= sort: 'SORT'
| record: 'RECORD'
| sortMerge: 'SORT-MERGE'
;
syntax FileNamePosition
syntax FileNamePosition = fileName: Id ('POSITION' Integer)?;
syntax AltAssignmentNameLiteral
syntax AltAssignmentNameLiteral
= literal: Literal
| assignmentName: Id
;
syntax CobwordKeywords
keyword CobwordKeywords
= 'ACCESS'
| 'ALTERNATE'
| 'APPLY'
| 'AREA'
| 'AREAS'
| 'CHARACTER'
| 'CONTAINS'
| 'DELIMITER'
| 'DUPLICATES'
| 'DYNAMIC'
| 'END'
| 'EVERY'
| 'FILE'
| 'FOR'
| 'INDEXED'
| 'IS'
| 'KEY'
| 'MODE'
| 'MULTIPLE'
| 'OF'
| 'ON'
| 'ORGANIZATION'
| 'PADDING'
| 'PASSWORD'
| 'POSITION'
| 'RANDOM'
| 'RECORD'
| 'RECORDS'
| 'RELATIVE'
| 'RERUN'
| 'RESERVE'
| 'SAME'
| 'SEQUENTIAL'
| 'SORT'
| 'SORT-MERGE'
| 'STANDARD-1'
| 'STATUS'
| 'TAPE'
| 'WITH'
| 'WRITE-ONLY'
;